Saving Trial Data from Arrays

mca
New Member

Posts: 4

Saving Trial Data from Arrays Mar 10, 2021 15:32:37 GMT

Quote

Post by mca on Mar 10, 2021 15:32:37 GMT

Hi everyone!

I am hoping to use a blocked design in a lexical decision task, with 5 categories of words (neutral, happy, anger, fear, disgust) and an equal number of nonwords. We want to block by word category, so there are 5 blocks. We are testing out blockorder to randomly select different orders, so that presentation of word categories is counterbalanced for participants. However, we also want nonwords randomly intermixed in each block and across blocks without repeating, so participants aren't seeing a string of words in a row and making very easy "word" decisions.
We are trying to avoid pseudo-randomizing by assigning nonwords to category lists, because then they would only ever be presented in that particular block. If possible, we want nonwords to be presented truly randomly, so we separated nonwords into their own table.

As it is, our code appears to be presenting word categories the way we want, which is blocked, and with word trials randomly presented within their respective blocks. We were also able to intermix nonwords by using arrays, and are currently using a randomized ‘coin flip’ variable in each task to randomly choose between words and nonwords trials (though if there's a better way to do this, all ears)! Our problem is that in our output, we are not able to collect RT or STATUS information on those nonword trials, presumably because they are part of an array. Furthermore, the nonwords are all presented back to back in output due to blockorder, not intermixed as they are presented to participants.

Q: Is it possible to save out RT and STATUS data from an array? We would like RT and STATUS data from all trials, word and nonword alike.
Our code is below, (notes in red):

options
startbutton text Click to begin
loading text Loading Experiment...

bitmaps
newinstructions1_revise1_1
newinstructions1_revise1_2
newInstructions1_REVISE1_3
newInstructions1_REVISE1_4
newInstructions1_REVISE1_5
fixpoint2
intermission1_6

fonts
arial 24

table words_neutral
"TIME" "word" 1 "NEUTRAL" 1
"RATTLE" "word" 1 "NEUTRAL" 1
"STOMACH" "word" 1 "NEUTRAL" 1
"ITEM" "word" 1 "NEUTRAL" 1

table words_happy
"SILK" "word" 1 "HAPPINESS" 2
"PASSION" "word" 1 "HAPPINESS" 2
"PASTA" "word" 1 "HAPPINESS" 2
"CUISINE" "word" 1 "HAPPINESS" 2

table words_anger
"HOSTILE" "word" 1 "ANGER" 3
"NUISANCE" "word" 1 "ANGER" 3
"INSULT" "word" 1 "ANGER" 3
"TRAITOR" "word" 1 "ANGER" 3

table words_fear
"HORROR" "word" 1 "FEAR" 4
"CYCLONE" "word" 1 "FEAR" 4
"PYTHON" "word" 1 "FEAR" 4
"DENTIST" "word" 1 "FEAR" 4

table words_disgust
"PERVERT" "word" 1 "DISGUST" 5
"FUNGUS" "word" 1 "DISGUST" 5
"DIRT" "word" 1 "DISGUST" 5
"MANURE" "word" 1 "DISGUST" 5

table nonwords
"MARGLE" "nonword" 2 "none" 0
"FAGHT" "nonword" 2 "none" 0
"SPFERE" "nonword" 2 "none" 0
"HEROIX" "nonword" 2 "none" 0
"FUT" "nonword" 2 "none" 0
"HAZ" "nonword" 2 "none" 0
"VURN" "nonword" 2 "none" 0
"FEVEN" "nonword" 2 "none" 0
"ENGENE" "nonword" 2 "none" 0
"DOBT" "nonword" 2 "none" 0
"PLECK" "nonword" 2 "none" 0
"MISTOL" "nonword" 2 "none" 0
"DUMAGE" "nonword" 2 "none" 0
"INHANE" "nonword" 2 "none" 0
"TRANK" "nonword" 2 "none" 0
"BULLUT" "nonword" 2 "none" 0
"LEGROSY" "nonword" 2 "none" 0
"DUSBPAX" "nonword" 2 "none" 0
"LOSUR" "nonword" 2 "none" 0
"TABLY" "nonword" 2 "none" 0

table demoWords
"PAPER" "word" 1 "none" "-1"
"JIOL" "nonword" 2 "none" "-1"
"YECV" "nonword" 2 "none" "-1"
"MINT" "word" 1 "none" "-1"
"GEFB" "nonword" 2 "none" "-1"
"FLOOR" "word" 1 "none" "-1"
"VANILLA" "word" 1 "none" "-1"
"TEST" "word" 1 "none" "-1"
"GOLKS" "nonword" 2 "none" "-1"

task prepare_array
table nonwords
set &&nonwords append @1
set &&nonwords shuffle
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 ## Here we are able to save column info, etc. but not RT or STATUS for nonwords

task lexical1
table words_neutral
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
set $x random from 1 2
if $x == 1
show text @1 0 0 0 0 0
fi
if $x == 2
set $nonwords &&nonwords remove first
show text $nonwords 0 0 0 0 0
fi
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

task lexical2
table words_happy
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
set $x random from 1 2
if $x == 1
show text @1 0 0 0 0 0
fi
if $x == 2
set $nonwords &&nonwords remove first
show text $nonwords 0 0 0 0 0
fi
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

task lexical3
table words_anger
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
set $x random from 1 2
if $x == 1
show text @1 0 0 0 0 0
fi
if $x == 2
set $nonwords &&nonwords remove first
show text $nonwords 0 0 0 0 0
fi
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

task lexical4
table words_fear
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
set $x random from 1 2
if $x == 1
show text @1 0 0 0 0 0
fi
if $x == 2
set $nonwords &&nonwords remove first
show text $nonwords 0 0 0 0 0
fi
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

task lexical5
table words_disgust
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
set $x random from 1 2
if $x == 1
show text @1 0 0 0 0 0
fi
if $x == 2
set $nonwords &&nonwords remove first
show text $nonwords 0 0 0 0 0
fi
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

task demoLexical
table demoWords
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
show text @1 0 0 0 0 0
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKNAME TABLEROW @1 @2 @3 @4 @5 RT STATUS

## Testing blockorder below to randomly pick among two possible orders

blockorder
instructions_round1
demo
instructions_round2
arrays
neutral
happy
anger
fear
disgust

blockorder
instructions_round1
demo
instructions_round2
arrays
disgust
fear
anger
happy
neutral

block instructions_round1
message newinstructions1_revise1_1
message newinstructions1_revise1_2
message newInstructions1_REVISE1_3
message newInstructions1_REVISE1_4
message newInstructions1_REVISE1_5
end

block demo
tasklist
demoLexical 9 all_before_repeat
end

block instructions_round2
message intermission1_6
end

block arrays
tasklist
prepare_array 20 all_before_repeat
end

block neutral
tasklist
lexical1 4 all_before_repeat
end

block happy
tasklist
lexical2 4 all_before_repeat
end

block anger
tasklist
lexical3 4 all_before_repeat
end

block fear
tasklist
lexical4 4 all_before_repeat
end

block disgust
tasklist
lexical5 4 all_before_repeat
end

silk
Experienced

Posts: 32

Saving Trial Data from Arrays Mar 10, 2021 23:36:06 GMT mca likes this

Quote

Post by silk on Mar 10, 2021 23:36:06 GMT

Hi there,

I just tried to make your script running on my side with the debug mode. It seems that your script doesn't work as intended : it simply stores a word that doesn't correspond to to the word that is shown on the screen (for instance showing "spfere", but saving "silk"). It's because you're working with both a table and an array to show your items : sometimes you show a non-word from an array but the values that are saved are from the table of real words. That's why you can't see any data for non-words (including RT and STATUS).

My fix would be the following :
- Create arrays to choose which non-word or which real word will be shown.
- Create a table to choose whether you're showing a non-word or a real word.

Have a look at the script below. I assumed that you wanted to have 4 real words and 4 non-words for each block. I didn't write all your tables, but you have to include them to make this script work. This script works perfectly fine on my side, I hope it will do so for you as well

Don't forget to compile your experiment in debug mode, it's handy to check what's wrong with your data.

table order      ### This table is for choosing the type of word to show.
"word" 1      ### 4 non-words and 4 real words will be shown in a
"nonword" 2      ### random order.
"word" 1      ### --> Make sure to use all_before_repeat for your task.
"nonword" 2 ### More observations per block means more lines in this table.
"word" 1
"nonword" 2
"word" 1
"nonword" 2

### TASKS ###

task array_nonwords             ### Task name has changed
table nonwords              ### but same script
set &&nonwords append @1
set &&nonwords shuffle

task array_neutral                ### Task to create an array for the
table words_neutral              ### real words of one condition (neutral)
set &&words_neutral append @1 ### --> Create a similar task for each of
set &&words_neutral shuffle ### your conditions (passion, disgust, etc.)

task lexical_neutral              ### Task to show your 4 "neutral" words +
table order                      ### 4 random non words.
keys a l                      ### Almost identical to yours, but with
show background 255 255 255      ### some changes.
show bitmap fixpoint2             ### No random value to choose between word
delay 500                      ### and non-word : I use the table "order" to
clear 2                      ### do that
draw off
if @1 == "word"                                  ### If the first column of the row
set $shown_word &&words_neutral remove first ### is "word", then pick a real
show text $shown_word 0 0 0 0 0                  ### word, else pick a non-word.
else                                              ### "else" can be used in if
set $shown_word &&nonwords remove first          ### statements in the latest
show text $shown_word 0 0 0 0 0                  ### version of PsyToolkit !
fi                                              ### It's very handy.
draw on
delay 500                        ### --> Create a similar task for each of
clear 3                     ### your conditions (passion, disgust, etc.)
show bitmap fixpoint2
readkey @2 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW $shown_word @1 @2 RT STATUS

task demoLexical              ### Nothing changed here
table demoWords
keys a l
show background 255 255 255
show bitmap fixpoint2
delay 500
clear 2
draw off
show text @1 0 0 0 0 0
draw on
delay 500
clear 3
show bitmap fixpoint2
readkey @3 999999
clear -1
save BLOCKORDER BLOCKNAME TABLEROW @1 @2 @3 RT STATUS

### BLOCKS ###

blockorder
arrays                  ### It's better to create your arrays first
instructions_round1
demo
instructions_round2
neutral

block instructions_round1
message newinstructions1_revise1_1
message newinstructions1_revise1_2
message newInstructions1_REVISE1_3
message newInstructions1_REVISE1_4
message newInstructions1_REVISE1_5

block demo
tasklist
demoLexical 9 all_before_repeat
end

block instructions_round2
message intermission1_6

block arrays                              ### This block is for all your arrays
tasklist
array_nonwords 20 all_before_repeat
array_neutral 4 all_before_repeat       ### --> Add a similar task for each of
end                                      ### your conditions (passion, disgust, etc.)

block neutral                              ### One of your 5 test blocks
tasklist                                ### --> Create a similar block for each of
lexical_neutral 8 all_before_repeat ### your conditions (passion, disgust, etc.)
end

danaleighton Regular Posts: 21	Saving Trial Data from Arrays Mar 11, 2021 17:29:46 GMT Quote Select Post Deselect Post Link to Post Member Give Gift Back to Top Post by danaleighton on Mar 11, 2021 17:29:46 GMT Mar 10, 2021 23:36:06 GMT silk said: I just tried to make your script running on my side with the debug mode. Wait, what? How do we enter debug mode? I missed that in the training!
	-- Dana C. Leighton, PhD Assistant Professor of Psychology, Texas A&M University—Texarkana Director, Peace and Justice Psychology Lab Office: University Center 222 • 903-334-6627 • dleighton@tamut.edu home: danaleighton.net • blog: danaleighton.edublogs.org preferred pronouns: he, him, his

matia
Very experienced

Posts: 77

Saving Trial Data from Arrays Mar 12, 2021 9:35:03 GMT

Quote

Post by matia on Mar 12, 2021 9:35:03 GMT

Mar 10, 2021 23:36:06 GMT silk said:

Hi there,

I just tried to make your script running on my side with the debug mode. It seems that your script doesn't work as intended : it simply stores a word that doesn't correspond to to the word that is shown on the screen (for instance showing "spfere", but saving "silk"). It's because you're working with both a table and an array to show your items : sometimes you show a non-word from an array but the values that are saved are from the table of real words. That's why you can't see any data for non-words (including RT and STATUS).

My fix would be the following :
- Create arrays to choose which non-word or which real word will be shown.
- Create a table to choose whether you're showing a non-word or a real word.

Have a look at the script below. I assumed that you wanted to have 4 real words and 4 non-words for each block. I didn't write all your tables, but you have to include them to make this script work. This script works perfectly fine on my side, I hope it will do so for you as well

Don't forget to compile your experiment in debug mode, it's handy to check what's wrong with your data.

Dear Silk,

I love the way You've helped on this experiment. I was hoping You could point me in the direction in which I would like to go.

I am trying to design an experiment that will require participants to go through a visual search task. Instead of the red letter T (used in the tutorial by prof. Stoet), I will have two different targets (target1 and target2, only one will should be presented on each trial), but this is not as problematic as the fact I would have tens of different distractors (let's say for the sake of the argument there will be exactly 10 of them).

In trying to adapt original Visual search task code - I've managed to design an experiment (but using table I created that consists of each stimulus name, position in the grid [4x4=16 different positions]). I would like to use new array feature so that I don't have to control for the position on which the stimuli is being presented (thus decreasing the number of trials each participant has to complete).

What I would like to do is the following: have an array in which there would be values that define random position of a target and a random positions of the given set of distractors

table conditions
   8  7  1  #so, @1 defines total no. of stimuli presented (distractors+target
  15  0  1  #@2 defines no. of GREEN distractors and @3 defines no. of RED distractors
  12  3  2  #@3 defines which target (blue OR yellow) is being presented on a given trial
   0  15 2
   8  8  0  #if it is 0, there is no target on the screen

task search
table conditions		
set &&targetset1 range 1 5 		        	#that's their order in stimuli dir (but I would like that each is presented at least
set &&targetset2 range 6 10				#certain no. of times (let's say three)
set &&targetsample1 &&targetset1 sample 1		#so on a given trial there should be maximum of 1 target stimulus
set &&targetsample1 append 
set &&distractorset1 range 11 20			#red distractors
set &&distractorsample1 &&distractorset1 sample @1	#random sample of red distractors BUT I DON'T THINK THIS IS CORRECT COMMAND
set &&distractorset2 range 21 30			#green distractors 			
set &&distractorsample2 &&distractorset2 sample @2	#random sample of green distractors
set &&searchset append &&distractorsample1  		#Shouldn't I end up with an array of length 1 (target) + 
set &&searchset append &&distractorsample2  		#@2 + @3 which will be eventually shuffled and each will get a position in the array? 
set &&searchset clear 			        	#This part I don't quite get (why clear it, when will it be clear etc.)
 if @5 == 2
  set &&searchset append &&targetset1 
 fi
 if @5 == 1
  set &&searchset append &&targetset2
 fi
if @5 == 0
set &&searchset append &&searchset ###I ASSUME THIS IS INCORRECT COMMAND BUT what to write to say "Just ignore and fill the array only with distractors"?
fi
set &&searchset shuffle no_repeat 1 4   ##I've been playing around with this 1 4 and 1 12, but nothing seems to change?
keys space
    show bitmap &&searchset[1]   -394 -288 #these are the grid coordinates
    show bitmap &&searchset[2]   -128 -288
    show bitmap &&searchset[3]    128 -288
    show bitmap &&searchset[4]    394 -288
    #
    show bitmap &&searchset[5]   -394 -96
    show bitmap &&searchset[6]   -128 -96
    show bitmap &&searchset[7]    128 -96
    show bitmap &&searchset[8]    394 -96
    #
    show bitmap &&searchset[9]   -394 96
    show bitmap &&searchset[10]  -128 96
    show bitmap &&searchset[11]   128 96
    show bitmap &&searchset[12]   394 96
    #
    show bitmap &&searchset[13]  -394 288
    show bitmap &&searchset[14]  -128 288
    show bitmap &&searchset[15]   128 288
    show bitmap &&searchset[16]   394 288
    #
    delay 1000
save  RT &&searchset #i need an information on where the target was presented and the number of different distractor types

block test
  tasklist
     search 20 #Ideally this would mean I have 20 trials (approximately 10 containing target 1 that will be randomly positioned somewhere in the grid)
  end

Any, and I mean any, kind of help will be greatly appreciated. I mean, the good thing about Psytoolkit is that I can make a work-around - just use a table with enormous number of rows and columns defining every possible situation that can happen. However, introduction of the arrays should make things easier

I would just like to emphasize that I've been playing with different commands trying to understand whether it is possible to sample a certain no of values but I don't think that the command from the online documentation set &&x &&y sample 10 is correct, because set asks to first define a new variable (so it should go set &&y &&x sample 10) but even in that case I just can't seem to get a random sample of values. I think it would benefit me greatly if this could be possible.

task search
  set &&distractors 1 2 3 4 5 6 7 8 9 10
  set &&distractors &&s1  sample 2
  set &&searchset 99 98 97 96 95
  set &&searchset append &&s1  
  show rectangle 100 100 100 100
  delay 500
  clear -1
save &&searchset

block block1
tasklist
search 3
end

Solving this, I think I could manage through trial and error to create arrays I need.

I hope this thread was not too confusing for anyone interested in helping out

Best regards,
Matia

Last Edit: Mar 12, 2021 11:50:33 GMT by matia: I have edited second code because it was too complex and couldn't be replicated.

The best time to plan an experiment is after you've done it.

silk
Experienced

Posts: 32

Saving Trial Data from Arrays Mar 12, 2021 19:14:37 GMT matia likes this

Quote

Post by silk on Mar 12, 2021 19:14:37 GMT

Hi,

The debug mode is an option you can select when you compile you experiment (see attachment). It allows you to see how your variables are saved with the save instruction. It's not much, but it's very handy to track errors in your script.

Dear Matia, I also wanted to use the sample instruction, but like you it didn't work. In fact, I discovered that the syntax of this instruction is wrong in the full documention. If you look at this awesome short-syntax page, it turns out that the syntax of the sample instruction is a bit more complex. See the script below.

task myTask
  set &&array 1 2 3 4 5
  set &&a sample 2 from &&array
  save &&a

For the visual search task, I agree that working with a huge table to have all the positions isn't very practical. I managed to script a task where each item is randomly attributed to a position in the 4x4 grid, using arrays. Basically, I needed 3 main arrays :

X coordinates
Y coordinates
A list of all items for 1 grid (= 1 row in your table)

With these three arrays, I can attribute a random item from the list to a slot in the grid. I repeat this process until the grid is totally filled. Have a look at my script below. It was a bit of a challenge to script this task. The big change here is that you don't have to write "show bitmap myPicture X Y" all the time. You can also easily add more distractors or targets if you want. I didn't use the sample instruction and I'm sure this script can be improved, but it works very good on my side. I hope it will help you with your experiment

bitmaps
  dis_green              ### The names of these bitmaps and the names in the &&bitmaps array must match !
  dis_red
  tar_blue
  tar_yellow

table conditions
  8   7   1  ### @1 = Green distractors
  15  0   1  ### @2 = Red distractors
  12  3   2  ### @3 = Target (1 blue / 2 yellow / 0 nothing)
  0   15  2
  8   8   0

############
### TASK ###
############

task search
  table conditions
  set $str 16                                                                          ### $str is the number of slots to fill in the grid
  set &&bitmaps dis_green dis_red tar_blue tar_yellow                                  ### Array with all your bitmaps for the grid (it's not the list of items)
  set &&x_coordinates 0 150 300 -150                                                   ### Arrays X & Y to locate each slot of the 4x4 grid
  set &&x_coordinates &&x_coordinates times 4                                          ### Different order for X and Y --> X : repeat 4x the whole array / Y : repeat 4x each value indivually 
  set &&y_coordinates 0 0 0 0 150 150 150 150 300 300 300 300 -150 -150 -150 -150      ### The combination of values at the same position in X and Y arrays always give you the coordinates of a unique slot.
  set &&green_distractors &&bitmaps[1] times @1                                        ### Array to retrieve the type and the number of items to add to the list
  set &&red_distractors &&bitmaps[2] times @2                                          ### More distractors/target means more arrays to build like these ones
  if @3 == 1
    set &&all_items append &&bitmaps[3]                    ### Check if target is blue or yellow, then add the target to the list of items
  fi
  if @3 == 2
    set &&all_items append &&bitmaps[4]
  fi
  set &&all_items append &&green_distractors               ### Append distractors to the list of items
  set &&all_items append &&red_distractors
  set &&all_items shuffle                                  ### Shuffle the list of items
  while $str != 0                                          ### While there is still an empty slit on the grid, fill the grid
    set $item &&all_items remove first                     ### Pick one item and remove it from the list
    set $str &&all_items size                              ### Say that one more slot has been filled
    set $x_coord &&x_coordinates remove first              ### Pick X and Y coordinates for one slot, and remove them from the list of coordinates to not fill twice a slot
    set $y_coord &&y_coordinates remove first
    show bitmap $item $x_coord $y_coord                    ### Fill the slot
  while-end
  delay 2000                                               ### All 16 slots have been filled

#############
### BLOCK ###
#############

block search_block
  tasklist
    search 20 fixed
  end

Attachments:

danaleighton
Regular

Posts: 21

Saving Trial Data from Arrays Mar 12, 2021 22:54:06 GMT

Quote

Post by danaleighton on Mar 12, 2021 22:54:06 GMT

Mar 12, 2021 19:14:37 GMT silk said:

The debug mode is an option you can select when you compile you experiment (see attachment). It allows you to see how your variables are saved with the save instruction. It's not much, but it's very handy to track errors in your script.

Yes -- I spent a little time twiddling around and figured out how to turn it on. Very helpful. I had a brief exchange with Gisjbert and he told me about the save -- I wondered what the Log area would display, but he said it's not been implemented yet. It would be nice if that area could be used to show what blocks and tasks it was executing at the moment, and maybe the value of variables...

--
Dana C. Leighton, PhD
Assistant Professor of Psychology, Texas A&M University—Texarkana
Director, Peace and Justice Psychology Lab
Office: University Center 222 • 903-334-6627 • dleighton@tamut.edu
home: danaleighton.net • blog: danaleighton.edublogs.org
preferred pronouns: he, him, his

matia
Very experienced

Posts: 77

Saving Trial Data from Arrays Mar 13, 2021 7:07:49 GMT

Quote

Post by matia on Mar 13, 2021 7:07:49 GMT

Mar 12, 2021 19:14:37 GMT silk said:

Hi,

The debug mode is an option you can select when you compile you experiment (see attachment). It allows you to see how your variables are saved with the save instruction. It's not much, but it's very handy to track errors in your script.

Dear Matia, I also wanted to use the sample instruction, but like you it didn't work. In fact, I discovered that the syntax of this instruction is wrong in the full documention. If you look at this awesome short-syntax page, it turns out that the syntax of the sample instruction is a bit more complex. See the script below.

task myTask
  set &&array 1 2 3 4 5
  set &&a sample 2 from &&array
  save &&a

Dear Silk, thank You so much for Your help! Unfortunately I am unable to test it immediately, but will get dive in by the end of the day, and will thank you once again for sure

Edit: I've managed to quickly run the script and it worked like a charm. It is a great example that I can adapt according to my needs. The only part that I am having trouble still is saving &&all_items (to get an information on the exact position of the target [but now that I am writing this I am thinking whether it is important to know this information since I probably won't analyze each individual trial?]). I have added a line at the end of the task codes save &&all_items - but don't receive any information. When saving $item - i get an info on the $item value in each trial.

This was a really quick and elaborate response from you, thanks for your time!

Best, Matia

Last Edit: Mar 13, 2021 8:30:06 GMT by matia

The best time to plan an experiment is after you've done it.

silk
Experienced

Posts: 32

Saving Trial Data from Arrays Mar 13, 2021 12:47:19 GMT

Quote

Post by silk on Mar 13, 2021 12:47:19 GMT

Hi,

Indeed, I also have trouble saving &&all_items (but remember that all values from this array are removed in the while loop). I also think it's because you normally can't save words in arrays. I used words to refer to bitmaps but you can also use indexes : "show bitmap $number_of_bitmap $x $y" where $number_of_bitmap stores a value like 2 and not a word - and it will show the second bitmap you called in the bitmaps section at the beginning of the script. Finally if you want to save the list with indexes, just copy &&all_items in another array before removing any value.

You can also play around with the locate instruction for arrays to find the position of the target item in the list. Actually this can be really useful because you may want to control the position of the target item so that it is never at the same position of the previous target item.

task locate
  set &&my_array 10 20 30 40 50
  set &&my_array shuffle
  set $x &&my_array locate 30     ### Store the position of 30 in &&my_array, store 0 if the value is not found

Last Edit: Mar 13, 2021 12:57:28 GMT by silk

matia
Very experienced

Posts: 77

Saving Trial Data from Arrays Mar 15, 2021 11:48:56 GMT silk likes this

Quote

Post by matia on Mar 15, 2021 11:48:56 GMT

Dear Silk,

I appreciate all you've done. As you said, it was not a piece of cake. You have helped me immensely. I will probably add or subtract something of your code, but it is very clear and precise.

Thanks again!

Best, Matia

The best time to plan an experiment is after you've done it.

mca
New Member

Posts: 4

Saving Trial Data from Arrays Mar 16, 2021 18:48:42 GMT

Quote

Post by mca on Mar 16, 2021 18:48:42 GMT

Mar 10, 2021 23:36:06 GMT silk said:

Have a look at the script below. I assumed that you wanted to have 4 real words and 4 non-words for each block. I didn't write all your tables, but you have to include them to make this script work. This script works perfectly fine on my side, I hope it will do so for you as well

Don't forget to compile your experiment in debug mode, it's handy to check what's wrong with your data.

Hi silk,

Thank you so much! You were correct on 4 words and 4 nonwords in a given block. This script worked perfectly after adding in additional tables, blockorders, etc. We really appreciate you taking the time, and patiently explaining everything.

Much appreciated!

mca
New Member

Posts: 4

Saving Trial Data from Arrays Mar 17, 2021 15:56:30 GMT

Quote

Post by mca on Mar 17, 2021 15:56:30 GMT

Mar 16, 2021 18:48:42 GMT mca said:

Mar 10, 2021 23:36:06 GMT silk said:

Have a look at the script below. I assumed that you wanted to have 4 real words and 4 non-words for each block. I didn't write all your tables, but you have to include them to make this script work. This script works perfectly fine on my side, I hope it will do so for you as well

Don't forget to compile your experiment in debug mode, it's handy to check what's wrong with your data.

Hi silk,

Thank you so much! You were correct on 4 words and 4 nonwords in a given block. This script worked perfectly after adding in additional tables, blockorders, etc. We really appreciate you taking the time, and patiently explaining everything.

Much appreciated!

I spoke too soon, unfortunately!

In testing further with debug mode, it appears that nonword items repeat across blocks, which is what we were trying to avoid by using arrays. We've included "all before repeat" for each, and this does seem to prevent nonwords and words from repeating within a given block, but does not prevent the nonwords from repeating across blocks. For example, "VURN" appears in the anger block, and then again in the neutral block, etc.

If anyone has any ideas on how to address this, it would be greatly appreciated!

silk
Experienced

Posts: 32

Saving Trial Data from Arrays Mar 17, 2021 16:50:04 GMT

Quote

Post by silk on Mar 17, 2021 16:50:04 GMT

Mar 17, 2021 15:56:30 GMT mca said:

I spoke too soon, unfortunately!

In testing further with debug mode, it appears that nonword items repeat across blocks, which is what we were trying to avoid by using arrays. We've included "all before repeat" for each, and this does seem to prevent nonwords and words from repeating within a given block, but does not prevent the nonwords from repeating across blocks. For example, "VURN" appears in the anger block, and then again in the neutral block, etc.

If anyone has any ideas on how to address this, it would be greatly appreciated!

Hi there,

It works fine on my side. No repetition after several trials. I've attached my script for your experiment (lexical_task.txt (8.24 KB)) with lexical tasks. Copy-paste it in a new experiment and see if it works as intented.

Saving Trial Data from Arrays

Post by mca on Mar 10, 2021 15:32:37 GMT

Post by silk on Mar 10, 2021 23:36:06 GMT

Post by danaleighton on Mar 11, 2021 17:29:46 GMT

Post by matia on Mar 12, 2021 9:35:03 GMT

Post by silk on Mar 12, 2021 19:14:37 GMT

Post by danaleighton on Mar 12, 2021 22:54:06 GMT

Post by matia on Mar 13, 2021 7:07:49 GMT

Post by silk on Mar 13, 2021 12:47:19 GMT

Post by matia on Mar 15, 2021 11:48:56 GMT

Post by mca on Mar 16, 2021 18:48:42 GMT

Post by mca on Mar 17, 2021 15:56:30 GMT

Post by silk on Mar 17, 2021 16:50:04 GMT